nixos-config/home/coding/agents/agents.nix

# AI agent system — OpenCode, Pi, and MCP server configuration.
# Relies on coding.agents options provided by home/common/default.nix
# (inputs.m3ta-nixpkgs.homeManagerModules.default).
{
  config,
  inputs,
  lib,
  pkgs,
  videoDrivers ? [],
  ...
}:
with lib; let
  npmGlobalPrefix = "${config.home.homeDirectory}/.npm-global";
in {
  home.file.".npmrc".text = ''
    prefix=${npmGlobalPrefix}
  '';
  home.sessionVariables.NPM_CONFIG_PREFIX = npmGlobalPrefix;

  imports = [
    # OpenCode and Pi agent configurations
    ./opencode.nix
    ./pi.nix
  ];

  coding.agents.skills = {
    agentsInput = inputs.agents;
    externalSkills = [
      {
        src = inputs.skills-anthropic;
        selectSkills = ["pdf" "docx" "frontend-design"];
      }
      {src = inputs.skills-vercel;}
      {src = inputs.skills-basecamp;}
      {src = inputs.skills-kestra;}
    ];
  };

  programs.mcp = {
    enable = true;
    servers = {
      DeepWiki = {
        url = "https://mcp.deepwiki.com/mcp";
      };
      Ref = {
        command = "bash";
        args = ["-c" "REF_API_KEY=$(cat /run/agenix/ref-key) exec bunx ref-tools-mcp@latest"];
      };
      Exa = {
        command = "bash";
        args = ["-c" "EXA_API_KEY=$(cat /run/agenix/exa-key) exec bunx exa-mcp-server@latest tools=web_search_exa"];
      };
      Outline = {
        url = "https://wiki.az-gruppe.com/mcp";
      };
      ContextMode = {
        command = "bash";
        args = ["-c" "exec bunx context-mode@latest"];
      };
      Honcho = {
        command = "bash";
        args = [
          "-c"
          ''exec bunx mcp-remote@latest https://mcp.honcho.dev --header "Authorization:Bearer $(cat /run/agenix/honcho-key)" --header "X-Honcho-User-Name:m3tam3re"''
        ];
      };
    };
  };

  home.packages = with pkgs; [
    agenix-cli
    agent-browser
    alejandra
    bc
    bun
    devpod
    gnumake
    cmake
    (python3.withPackages (ps:
      with ps; [
        pip
        uv
        numba
        numpy
        torch
        srt
      ]))
    pyrefly
    nixd
    nix-update
    nodejs
    (qmd.override {
      vulkanSupport = videoDrivers == ["amdgpu"];
      cudaSupport = videoDrivers == ["nvidia"];
    })
    openshell
    openspec
    pi-coding-agent
    sidecar
    tailwindcss
    tailwindcss-language-server
    td
  ];
}