Files
nixos-config/hosts/m3-hermes/services/ai-memory.nix
T

55 lines
2.2 KiB
Nix
Raw Normal View History

{
config,
pkgs,
...
}: let
# Mesh-only via interface match on wt0 (NetBird) — an IPv4 CIDR in -s
# would abort the ip6tables run of ip46tables and fail the unit.
port = config.m3ta.ports.get "ai-memory";
in {
# ── ai-memory server ──────────────────────────────────────────────────
# Shared agent memory for all hosts (private + work), see
# https://aimemory.sh. Clients: m3ta-home `coding.aiMemory`.
#
# Flow: Agent → memory.m3ta.dev (TLS via m3-atlas Traefik) → Netbird → :${toString port}
# Hermes on this host talks to 127.0.0.1 directly.
services.ai-memory = {
enable = true;
# Same build as the clients (m3ta-home uses llm-agents.ai-memory),
# prebuilt via the numtide cache instead of compiling the flake.
package = pkgs.llm-agents.ai-memory;
bind = "0.0.0.0";
inherit port;
enableWeb = true;
# Root bearer, token pepper, recovery token, cookie/proxy settings and
# the LLM provider key. Never put any of these into `settings`.
ageSecret = "ai-memory-server-env";
settings = {
allowed_hosts = ["memory.m3ta.dev" "localhost" "127.0.0.1" "::1"];
# One operator, several workspaces (private, az, home): keep one
# cross-project profile for all of them. With database users the
# profile is off unless enabled explicitly.
profile = {
enabled = true;
share = "global";
};
# Shared server: auto-improvement proposals wait for approval.
auto_improve.require_approval = true;
};
};
# A changed secret (model, keys, tokens) does not change the unit file, so
# without this the running server keeps the old environment after a switch.
systemd.services.ai-memory.restartTriggers = [config.age.secrets."ai-memory-server-env".file];
networking.firewall = {
extraCommands = ''
# Allow ai-memory only from Netbird mesh VPN
ip46tables -A nixos-fw -p tcp --dport ${toString port} -i wt0 -j nixos-fw-accept
'';
extraStopCommands = ''
ip46tables -D nixos-fw -p tcp --dport ${toString port} -i wt0 -j nixos-fw-accept 2>/dev/null || true
'';
};
}