- new ai-agents overlay (applied after m3ta-nixpkgs, which re-exports
opencode-desktop from its own older v1 flake input):
* opencode -> llm-agents.opencode2 (2.0.16), binary renamed back to
'opencode' so keybinds/wrappers keep working
* opencode-desktop -> llm-agents.opencode-desktop (1.18.32, newest
existing desktop release; no v2 desktop app upstream)
- bump llm-agents lock to 8bec0ce1 (opencode2 2.0.16)
- m3-hermes keeps llm-agents.opencode (v1) for now
99 lines
4.0 KiB
Nix
99 lines
4.0 KiB
Nix
{inputs, ...}: {
|
|
# This one brings our custom packages from the 'pkgs' directory
|
|
# additions = final: prev:
|
|
# (import ../pkgs {pkgs = final;})
|
|
# // {rose-pine-hyprcursor = inputs.rose-pine-hyprcursor.packages.${prev.system}.default;};
|
|
|
|
# This one contains whatever you want to overlay
|
|
# You can change versions, add patches, set compilation flags, anything really.
|
|
# https://nixos.wiki/wiki/Overlays
|
|
modifications = final: prev: {
|
|
# aardvark-dns 2.x has a DNS forwarding bug breaking external name
|
|
# resolution in podman networks — pin to last 1.x from nixpkgs-stable.
|
|
aardvark-dns = import ./mods/aardvark-dns.nix {inherit (final) stable;};
|
|
|
|
# font-manager 0.9.4 does not compile against gtk4 4.22 (Vala errors
|
|
# in Gtk.DragIcon.get_for_drag) — apply the upstream fix from
|
|
# FontManager/font-manager#468 until our nixpkgs lock carries it.
|
|
# font-manager = import ./mods/font-manager.nix {inherit prev;};
|
|
|
|
# rofi-pass{,-wayland} were removed from nixpkgs on 2026-09-04
|
|
# ("unmaintained upstream"). m3ta-home's rofi module and the Hyprland
|
|
# mod+P keybind still use them — resurrect via overlay until a
|
|
# maintained replacement is packaged upstream.
|
|
rofi-pass = final.callPackage ./mods/rofi-pass.nix {};
|
|
rofi-pass-wayland = final.callPackage ./mods/rofi-pass.nix {backend = "wayland";};
|
|
};
|
|
|
|
# Top-level pins for the OpenCode packages from llm-agents. Applied
|
|
# AFTER m3ta-nixpkgs' overlay in hosts/common/default.nix — that overlay
|
|
# re-exports `opencode-desktop` from its own `opencode` flake input
|
|
# (github:anomalyco/opencode, v1 line), which would clobber a pin placed
|
|
# in `modifications`.
|
|
ai-agents = final: _prev: {
|
|
# OpenCode TUI: nixpkgs' top-level `opencode` still tracks the v1 line
|
|
# (1.18.x) and llm-agents' shared-nixpkgs overlay namespaces everything
|
|
# under `pkgs.llm-agents.*` by design. Expose the v2 CLI (npm
|
|
# @opencode/cli latest) under the canonical top-level attribute so
|
|
# home-manager's programs.opencode and m3ta-home pick it up. Upstream
|
|
# installs the binary as `opencode2` (so v1/v2 can coexist in the
|
|
# llm-agents package set) — rename it back to `opencode` to keep
|
|
# keybinds, aliases, and wrappers working.
|
|
opencode = final.symlinkJoin {
|
|
name = "opencode-${final.llm-agents.opencode2.version}";
|
|
paths = [final.llm-agents.opencode2];
|
|
postBuild = ''
|
|
mv $out/bin/opencode2 $out/bin/opencode
|
|
'';
|
|
meta = (final.llm-agents.opencode2.meta or {}) // {mainProgram = "opencode";};
|
|
};
|
|
|
|
# OpenCode Desktop: no v2 desktop app exists upstream (anomalyco/opencode
|
|
# ends at v1.18.32); track the newest v1 release from llm-agents instead
|
|
# of the older m3ta-nixpkgs pin (1.18.30+95daf90).
|
|
opencode-desktop = final.llm-agents.opencode-desktop;
|
|
};
|
|
|
|
# temp-packages = final: _prev: {
|
|
# temp = import inputs.nixpkgs-9e9486b {
|
|
# system = final.stdenv.hostPlatform.system;
|
|
# config.allowUnfree = true;
|
|
# };
|
|
# };
|
|
|
|
stable-packages = final: _prev: {
|
|
stable = import inputs.nixpkgs-stable {
|
|
system = final.stdenv.hostPlatform.system;
|
|
config.allowUnfree = true;
|
|
};
|
|
};
|
|
|
|
# pinned-packages = final: _prev: {
|
|
# pinned = import inputs.nixpkgs-9472de4 {
|
|
# system = final.stdenv.hostPlatform.system;
|
|
# config.allowUnfree = true;
|
|
# };
|
|
# };
|
|
|
|
# locked-packages = final: _prev: {
|
|
# locked = import inputs.nixpkgs-locked {
|
|
# system = final.stdenv.hostPlatform.system;
|
|
# config.allowUnfree = true;
|
|
# };
|
|
# };
|
|
|
|
master-packages = final: _prev: {
|
|
master = import inputs.nixpkgs-master {
|
|
system = final.stdenv.hostPlatform.system;
|
|
config.allowUnfree = true;
|
|
};
|
|
};
|
|
|
|
# llm-agent packages (qmd, herdr, beads, …) come from
|
|
# inputs.llm-agents.overlays.shared-nixpkgs, applied directly in
|
|
# hosts/common/default.nix. They are consumed via the `pkgs.llm-agents.*`
|
|
# namespace — no flattening to top-level attributes (that clobbered
|
|
# nixpkgs attrs like buildNpmPackage/fetchPnpmDeps and needed a
|
|
# hard-to-maintain blocklist).
|
|
}
|