first

pkgs/code2prompt/default.nix

@@ -0,0 +1,37 @@
+{
+  lib,
+  fetchFromGitHub,
+  rustPlatform,
+  pkg-config,
+  perl,
+  openssl,
+}:
+rustPlatform.buildRustPackage rec {
+  pname = "code2prompt";
+  version = "4.0.2";
+
+  src = fetchFromGitHub {
+    owner = "mufeedvh";
+    repo = "code2prompt";
+    rev = "v${version}";
+    hash = "sha256-2ac/ZobL+4cQz94JjtS+JC7qsPE5lktznlhMAgSJa8g=";
+  };
+
+  cargoLock = {
+    lockFile = src + "/Cargo.lock";
+  };
+
+  buildAndTestSubdir = "crates/code2prompt";
+
+  nativeBuildInputs = [pkg-config perl];
+
+  buildInputs = [openssl];
+
+  meta = with lib; {
+    description = "A CLI tool that converts your codebase into a single LLM prompt with a source tree, prompt templating, and token counting";
+    homepage = "https://github.com/mufeedvh/code2prompt";
+    license = licenses.mit;
+    platforms = platforms.linux;
+    mainProgram = "code2prompt";
+  };
+}

pkgs/default.nix

@@ -0,0 +1,11 @@
+{pkgs, ...}: {
+  # Custom packages registry
+  # Each package is defined in its own directory under pkgs/
+  code2prompt = pkgs.callPackage ./code2prompt {};
+  hyprpaper-random = pkgs.callPackage ./hyprpaper-random {};
+  launch-webapp = pkgs.callPackage ./launch-webapp {};
+  msty-studio = pkgs.callPackage ./msty-studio {};
+  pomodoro-timer = pkgs.callPackage ./pomodoro-timer {};
+  tuxedo-backlight = pkgs.callPackage ./tuxedo-backlight {};
+  zellij-ps = pkgs.callPackage ./zellij-ps {};
+}

pkgs/hyprpaper-random/default.nix

@@ -0,0 +1,72 @@
+{
+  lib,
+  stdenv,
+  writeShellScriptBin,
+  fd,
+  hyprland,
+  coreutils,
+  gawk,
+}: let
+  script = writeShellScriptBin "hyprpaper-random" ''
+    #!/usr/bin/env bash
+    set -euo pipefail
+
+    # Directory (override with WALLPAPER_DIR)
+    DIR="''${WALLPAPER_DIR:-''${XDG_CONFIG_HOME:-$HOME/.config}/hypr/wallpapers}"
+
+    HYPRCTL="${hyprland}/bin/hyprctl"
+    FD="${fd}/bin/fd"
+    SHUF="${coreutils}/bin/shuf"
+    TR="${coreutils}/bin/tr"
+    AWK="${gawk}/bin/awk"
+
+    # Pick one random image (null-safe)
+    WALLPAPER="$(
+      "$FD" . "$DIR" -t f -e jpg -e jpeg -e png -e webp -e avif -0 --follow --hidden \
+        | "$SHUF" -z -n1 \
+        | "$TR" -d '\0'
+    )"
+
+    if [[ -z "''${WALLPAPER:-}" ]]; then
+      echo "No wallpapers found in: $DIR" >&2
+      exit 1
+    fi
+
+    # Preload so hyprpaper can use it
+    "$HYPRCTL" hyprpaper preload "$WALLPAPER" >/dev/null 2>&1 || true
+
+    # Apply to all monitors
+    "$HYPRCTL" monitors \
+      | "$AWK" '/^Monitor /{print $2}' \
+      | while IFS= read -r mon; do
+          [ -n "$mon" ] && "$HYPRCTL" hyprpaper wallpaper "$mon,$WALLPAPER"
+        done
+
+    exit 0
+  '';
+in
+  stdenv.mkDerivation {
+    pname = "hyprpaper-random";
+    version = "0.1.1";
+
+    dontUnpack = true;
+
+    buildInputs = [
+      fd
+      hyprland
+      coreutils
+      gawk
+    ];
+
+    installPhase = ''
+      mkdir -p "$out/bin"
+      ln -s ${script}/bin/hyprpaper-random "$out/bin/hyprpaper-random"
+    '';
+
+    meta = {
+      description = "Minimal random wallpaper setter for Hyprpaper";
+      license = lib.licenses.mit;
+      platforms = lib.platforms.linux;
+      mainProgram = "hyprpaper-random";
+    };
+  }

pkgs/launch-webapp/default.nix

@@ -0,0 +1,41 @@
+{
+  lib,
+  stdenv,
+  writeShellScriptBin,
+}: let
+  launcher = writeShellScriptBin "launch-webapp" ''
+    #!/usr/bin/env bash
+
+    browser=$(xdg-settings get default-web-browser)
+
+    case "$browser" in
+      google-chrome*) browser_bin="google-chrome" ;;
+      brave-browser*) browser_bin="brave-browser" ;;
+      microsoft-edge*) browser_bin="microsoft-edge" ;;
+      opera*) browser_bin="opera" ;;
+      vivaldi*) browser_bin="vivaldi" ;;
+      *) browser_bin="chromium" ;;
+    esac
+
+    exec_cmd="/etc/profiles/per-user/$USER/bin/$browser_bin"
+    exec setsid uwsm app -- "$exec_cmd" --app="$1" ''${@:2}
+  '';
+in
+  stdenv.mkDerivation {
+    pname = "launch-webapp";
+    version = "0.1.0";
+
+    dontUnpack = true;
+
+    installPhase = ''
+      mkdir -p $out/bin
+      ln -s ${launcher}/bin/launch-webapp $out/bin/launch-webapp
+    '';
+
+    meta = {
+      description = "Launches a web app using your default browser in app mode.";
+      license = lib.licenses.mit;
+      platforms = lib.platforms.linux;
+      mainProgram = "launch-webapp";
+    };
+  }

pkgs/msty-studio/default.nix

@@ -0,0 +1,45 @@
+{
+  appimageTools,
+  fetchurl,
+  lib,
+  nodejs,
+  nodePackages,
+  uv,
+  python3,
+  makeWrapper,
+}: let
+  pname = "msty-studio";
+  version = "2.0.0-beta.4";
+  src = fetchurl {
+    url = "https://next-assets.msty.studio/app/alpha/linux/MstyStudio_x86_64.AppImage";
+    sha256 = "sha256-zJcGK7QEL3ROgVJy13mMdY/437H3Zx8EwSXy7rEhV9w=";
+  };
+  appimageContents = appimageTools.extractType2 {inherit pname version src;};
+in
+  appimageTools.wrapType2 {
+    inherit pname version src;
+    nativeBuildInputs = [makeWrapper];
+
+    extraPkgs = pkgs: [
+      nodejs
+      nodePackages.npm
+      uv
+      python3
+    ];
+
+    extraInstallCommands = ''
+      install -m 444 -D ${appimageContents}/MstyStudio.desktop -t $out/share/applications
+      substituteInPlace $out/share/applications/MstyStudio.desktop \
+              --replace 'Exec=AppRun' 'Exec=${pname}'
+      install -m 444 -D ${appimageContents}/MstyStudio.png \
+              $out/share/icons/hicolor/256x256/apps/MstyStudio.png
+              wrapProgram $out/bin/${pname} \
+                      --prefix PATH : ${nodejs}/bin:${nodePackages.npm}/bin:${uv}/bin:${python3}/bin
+    '';
+    meta = {
+      description = "Msty Studio enables advanced, privacy‑preserving AI workflows entirely on your local machine.";
+      license = lib.licenses.unfree;
+      platforms = lib.platforms.linux;
+      mainProgram = "msty-studio";
+    };
+  }

pkgs/pomodoro-timer/default.nix

@@ -0,0 +1,92 @@
+{
+  lib,
+  stdenv,
+  writeShellScriptBin,
+  timer,
+  kitty,
+  rofi,
+  libnotify,
+  speechd,
+}: let
+  launcher = writeShellScriptBin "launch-timer" ''
+    #!/bin/bash
+
+    validate_time() {
+      local input=$1
+      if [[ $input =~ ^[0-9]+[mhs]$ ]]; then
+        return 0
+      else
+        return 1
+      fi
+    }
+
+    notify_end() {
+      local session_name=$1
+      ${libnotify}/bin/notify-send "Pomodoro" "$session_name session ended!"
+      ${speechd}/bin/spd-say "$session_name session ended"
+    }
+
+    start_timer() {
+      local duration=$1
+      local session_name=$2
+      kitty \
+        --class="floating-pomodoro" \
+        --title="floating-pomodoro" \
+        ${timer}/bin/timer $duration
+      notify_end "$session_name"
+    }
+
+    # Show rofi menu with options
+    selected=$(printf "work\nbreak\ncustom" | rofi -dmenu -p "Work Timer:" -l 3)
+
+    # Exit if no selection was made
+    [ -z "$selected" ] && exit
+
+    case $selected in
+      "work")
+        start_timer "45m" "work"
+        ;;
+      "break")
+        start_timer "10m" "break"
+        ;;
+      "custom")
+        # Show input dialog for custom time
+        custom_time=$(rofi -dmenu -p "Enter time (e.g., 25m, 1h, 30s):" -l 0)
+
+        # Validate input and start timer
+        if [ ! -z "$custom_time" ] && validate_time "$custom_time"; then
+          start_timer "$custom_time" "custom"
+        else
+          ${libnotify}/bin/notify-send "Invalid time format" "Please use format: 30s, 25m, or 1h"
+          exit 1
+        fi
+        ;;
+    esac
+  '';
+in
+  stdenv.mkDerivation {
+    pname = "work-timer";
+    version = "0.1.0";
+
+    dontUnpack = true;
+
+    buildInputs = [
+      timer
+      kitty
+      rofi
+      libnotify
+      speechd
+    ];
+
+    installPhase = ''
+      mkdir -p $out/bin
+      ln -s ${launcher}/bin/launch-timer $out/bin/launch-timer
+    '';
+
+    meta = {
+      description = "A Work timer.";
+      license = lib.licenses.mit;
+      platforms = lib.platforms.linux;
+      mainProgram = "launch-timer";
+    };
+  }

pkgs/tuxedo-backlight/default.nix

@@ -0,0 +1,26 @@
+{writeShellScriptBin}:
+writeShellScriptBin "tuxedo-backlight" ''
+  # all keys
+  echo '0 150 255' | tee /sys/class/leds/rgb:kbd_backlight*/multi_intensity
+
+  # DEL key
+  echo '255 0 155' | tee /sys/class/leds/rgb:kbd_backlight_15/multi_intensity
+
+  # ESC key
+  echo '255 0 155' | tee /sys/class/leds/rgb:kbd_backlight/multi_intensity
+
+  # function and Fn keys
+  for i in {1..12} 102; do
+      echo '0 255 80' | tee /sys/class/leds/rgb:kbd_backlight_$i/multi_intensity
+  done
+
+  # complete numblock and keys above
+  for i in {16..19} {36..39} {56..59} {76..79} {96..99} {117..119}; do
+      echo '255 150 0' | tee /sys/class/leds/rgb:kbd_backlight_$i/multi_intensity
+  done
+
+  # arrow keys
+  for i in 95 {114..116}; do
+      echo '0 255 80' | tee /sys/class/leds/rgb:kbd_backlight_$i/multi_intensity
+  done
+''

pkgs/zellij-ps/default.nix

@@ -0,0 +1,42 @@
+{
+  lib,
+  stdenv,
+  fetchFromGitea,
+  fish,
+  fd,
+  fzf,
+  zellij,
+}:
+with lib;
+  stdenv.mkDerivation {
+    pname = "zellij-ps";
+    version = "0.1.0";
+
+    src = fetchFromGitea {
+      domain = "code.m3ta.dev";
+      owner = "m3tam3re";
+      repo = "helper-scripts";
+      rev = "08a3217b83391c1110545c1ee3161eecd5dbe5e9";
+      sha256 = "1sc4i58mwcg3qsq0wwl5rvk08ykbxc497bq7mrxiirndsarskby7";
+    };
+
+    propagatedBuildInputs = [fish fd fzf zellij];
+
+    nativeBuildInputs = [];
+    installPhase = ''
+      mkdir -p $out/bin
+      substitute zellij-ps.fish $out/bin/zellij-ps \
+        --replace-fail 'fd --type' '${fd}/bin/fd --type' \
+        --replace-fail 'fzf --preview' '${fzf}/bin/fzf --preview' \
+        --replace-fail 'zellij --layout' '${zellij}/bin/zellij --layout' \
+        --replace-fail 'pgrep -c zellij' 'pgrep -c ${zellij}/bin/zellij'
+      chmod +x $out/bin/zellij-ps
+    '';
+
+    meta = {
+      description = "A small project script for zellij";
+      license = lib.licenses.mit;
+      platforms = platforms.unix;
+      mainProgram = "zelli-ps";
+    };
+  }