chore(nix): remove deprecated packages

- Remove opencode flake input (old v1.4.3 URL, superseded)
- Remove code2prompt package
- Remove opencode-desktop package

pkgs/code2prompt/default.nix

@@ -1,40 +0,0 @@
-{
-  lib,
-  fetchFromGitHub,
-  nix-update-script,
-  rustPlatform,
-  pkg-config,
-  perl,
-  openssl,
-}:
-rustPlatform.buildRustPackage rec {
-  pname = "code2prompt";
-  version = "4.2.0";
-
-  src = fetchFromGitHub {
-    owner = "mufeedvh";
-    repo = "code2prompt";
-    rev = "v${version}";
-    hash = "sha256-Gh8SsSTZW7QlyyC3SWJ5pOK2x85/GT7+LPJn2Jeczpc=";
-  };
-
-  cargoLock = {
-    lockFile = src + "/Cargo.lock";
-  };
-
-  buildAndTestSubdir = "crates/code2prompt";
-
-  nativeBuildInputs = [pkg-config perl];
-
-  buildInputs = [openssl];
-
-  passthru.updateScript = nix-update-script {};
-
-  meta = with lib; {
-    description = "A CLI tool that converts your codebase into a single LLM prompt with a source tree, prompt templating, and token counting";
-    homepage = "https://github.com/mufeedvh/code2prompt";
-    license = licenses.mit;
-    platforms = platforms.linux;
-    mainProgram = "code2prompt";
-  };
-}

pkgs/default.nix

@@ -18,7 +18,6 @@ in {
 
   sidecar = pkgs.callPackage ./sidecar {};
   td = pkgs.callPackage ./td {};
-  code2prompt = pkgs.callPackage ./code2prompt {};
   eigent = pkgs.callPackage ./eigent {};
   hyprpaper-random = pkgs.callPackage ./hyprpaper-random {};
   launch-webapp = pkgs.callPackage ./launch-webapp {};
@@ -39,13 +38,4 @@ in {
 
   basecamp = inputs.basecamp.packages.${system}.default;
   openspec = inputs.openspec.packages.${system}.default;
-
-  # ── Modified packages ────────────────────────────────────────────
-  # Imported from flake inputs but built with local overrides.
-
-  # inputs.opencode is used for:
-  #   - opencode binary (copied into the Tauri sidecars directory)
-  #   - node_modules (with FOD hash fix for upstream issue #11755)
-  #   - src + patches (via inputs.opencode)
-  opencode-desktop = pkgs.callPackage ./opencode-desktop {inherit inputs;};
 }

pkgs/opencode-desktop/default.nix

@@ -1,114 +0,0 @@
-{
-  lib,
-  stdenv,
-  symlinkJoin,
-  makeWrapper,
-  rustPlatform,
-  pkg-config,
-  cargo-tauri,
-  bun,
-  nodejs,
-  cargo,
-  rustc,
-  jq,
-  wrapGAppsHook4,
-  dbus,
-  glib,
-  gtk4,
-  libsoup_3,
-  librsvg,
-  libappindicator,
-  glib-networking,
-  openssl,
-  webkitgtk_4_1,
-  gst_all_1,
-  inputs ? null,
-}: let
-  # Get upstream opencode package for shared attributes
-  opencode = inputs.opencode.packages.${stdenv.hostPlatform.system}.default;
-
-  # Workaround for https://github.com/anomalyco/opencode/issues/11755
-  # Upstream is missing outputHashes for git dependencies
-  # Also fix stale npm deps hash in upstream node_modules FOD
-  fixedNodeModules = opencode.node_modules.overrideAttrs {
-    outputHash = "sha256-285KZ7rZLRoc6XqCZRHc25NE+mmpGh/BVeMpv8aPQtQ=";
-  };
-
-  opencode-desktop = rustPlatform.buildRustPackage (finalAttrs: {
-    pname = "opencode-desktop";
-    version = opencode.version;
-    src = opencode.src;
-    node_modules = fixedNodeModules;
-    patches = opencode.patches;
-
-    cargoRoot = "packages/desktop/src-tauri";
-    cargoLock = {
-      lockFile = finalAttrs.src + "/packages/desktop/src-tauri/Cargo.lock";
-      outputHashes = {
-        "specta-2.0.0-rc.22" = "sha256-YsyOAnXELLKzhNlJ35dHA6KGbs0wTAX/nlQoW8wWyJQ=";
-        "tauri-2.9.5" = "sha256-dv5E/+A49ZBvnUQUkCGGJ21iHrVvrhHKNcpUctivJ8M=";
-        "tauri-specta-2.0.0-rc.21" = "sha256-n2VJ+B1nVrh6zQoZyfMoctqP+Csh7eVHRXwUQuiQjaQ=";
-      };
-    };
-    buildAndTestSubdir = finalAttrs.cargoRoot;
-
-    nativeBuildInputs =
-      [pkg-config cargo-tauri.hook bun nodejs cargo rustc jq makeWrapper]
-      ++ lib.optionals stdenv.hostPlatform.isLinux [wrapGAppsHook4];
-
-    buildInputs = lib.optionals stdenv.isLinux [
-      dbus
-      glib
-      gtk4
-      libsoup_3
-      librsvg
-      libappindicator
-      glib-networking
-      openssl
-      webkitgtk_4_1
-      gst_all_1.gstreamer
-      gst_all_1.gst-plugins-base
-      gst_all_1.gst-plugins-good
-      gst_all_1.gst-plugins-bad
-    ];
-
-    strictDeps = true;
-
-    preBuild = ''
-      cp -a ${finalAttrs.node_modules}/{node_modules,packages} .
-      chmod -R u+w node_modules packages
-      patchShebangs node_modules
-      patchShebangs packages/desktop/node_modules
-
-      mkdir -p packages/desktop/src-tauri/sidecars
-      cp ${opencode}/bin/opencode packages/desktop/src-tauri/sidecars/opencode-cli-${stdenv.hostPlatform.rust.rustcTarget}
-    '';
-
-    tauriBuildFlags = ["--config" "tauri.prod.conf.json" "--no-sign"];
-
-    postFixup = lib.optionalString stdenv.hostPlatform.isLinux ''
-      mv $out/bin/OpenCode $out/bin/opencode-desktop
-      sed -i 's|^Exec=OpenCode$|Exec=opencode-desktop|' $out/share/applications/OpenCode.desktop
-    '';
-  });
-  # Wrapper for Wayland support
-in
-  symlinkJoin {
-    name = "opencode-desktop";
-    paths = [opencode-desktop];
-
-    nativeBuildInputs = [makeWrapper];
-
-    postBuild = ''
-      wrapProgram $out/bin/opencode-desktop \
-        --run 'if [[ "$NIXOS_OZONE_WL" == "1" ]]; then export OC_ALLOW_WAYLAND=1; fi'
-    '';
-
-    meta = {
-      description = "OpenCode Desktop App with Wayland support";
-      homepage = "https://opencode.ai";
-      license = lib.licenses.mit;
-      platforms = lib.platforms.linux;
-      mainProgram = "opencode-desktop";
-    };
-  }