m3tam3re
69fce234a8
basecamp: bump flake input to github:basecamp/basecamp-cli/v0.8.0-rc.1. The rc.1 tag ships a stale nix/package.nix whose vendorHash does not match the tagged go.sum (buildGoModule FOD fails) and whose `version` was not bumped (still reads 0.7.2). Override both on the pass-through so the input builds and reports 0.8.0-rc.1. Drop the override back to a plain pass-through once upstream fixes package.nix for the 0.8.0 final. vibetyper: 1.4.0 -> 1.4.1 with refreshed AppImage sha256.
45 lines
1.4 KiB
Nix
45 lines
1.4 KiB
Nix
# last-modified: Fri, 24 Jul 2026 10:50:57 GMT
|
|
{
|
|
appimageTools,
|
|
fetchurl,
|
|
lib,
|
|
makeWrapper,
|
|
}: let
|
|
pname = "vibetyper";
|
|
version = "1.4.1";
|
|
# Upstream publishes to an unversioned URL — ./update.sh watches Last-Modified
|
|
# and refreshes the sha256 when the binary changes. Bump `version` manually.
|
|
src = fetchurl {
|
|
url = "https://cdn.vibetyper.com/releases/linux/VibeTyper.AppImage";
|
|
sha256 = "sha256-mhXWEKvDgzxJrqIjzUWpfPM8qwKf6YYLsbjqqjtEk5s=";
|
|
};
|
|
appimageContents = appimageTools.extractType2 {inherit pname version src;};
|
|
in
|
|
appimageTools.wrapType2 {
|
|
inherit pname version src;
|
|
|
|
nativeBuildInputs = [makeWrapper];
|
|
|
|
extraPkgs = pkgs: [pkgs.fuse2];
|
|
|
|
extraInstallCommands = ''
|
|
install -m 444 -D ${appimageContents}/vibe-typer.desktop -t $out/share/applications
|
|
substituteInPlace $out/share/applications/vibe-typer.desktop \
|
|
--replace 'Exec=AppRun --no-sandbox' 'Exec=${pname}'
|
|
install -m 444 -D ${appimageContents}/vibe-typer.png \
|
|
$out/share/icons/hicolor/512x512/apps/vibe-typer.png
|
|
wrapProgram $out/bin/${pname} \
|
|
--set VIBE_DISABLE_HYPRLAND_INDICATOR_NO_BLUR 1
|
|
'';
|
|
|
|
passthru.updateScript = ./update.sh;
|
|
|
|
meta = {
|
|
description = "VibeTyper - AI-powered typing assistant";
|
|
homepage = "https://vibetyper.com";
|
|
license = lib.licenses.unfree;
|
|
platforms = lib.platforms.linux;
|
|
mainProgram = "vibetyper";
|
|
};
|
|
}
|