m3ta-chiron
e29d274918
- Refresh AppImage hash (last-modified: Wed, 16 Sep 2026) - Replace dead VIBE_DISABLE_HYPRLAND_INDICATOR_NO_BLUR env var with VIBE_DISABLE_WLROOTS_INDICATOR_RULES (renamed upstream in 1.5.x) - 1.5.x fixes: multi-monitor Wayland indicator placement (1.3.4), stuck Magic Formatter previews (1.3.5)
45 lines
1.4 KiB
Nix
45 lines
1.4 KiB
Nix
# last-modified: Wed, 16 Sep 2026 09:48:47 GMT
|
|
{
|
|
appimageTools,
|
|
fetchurl,
|
|
lib,
|
|
makeWrapper,
|
|
}: let
|
|
pname = "vibetyper";
|
|
version = "1.5.2";
|
|
# Upstream publishes to an unversioned URL — ./update.sh watches Last-Modified
|
|
# and refreshes the sha256 when the binary changes. Bump `version` manually.
|
|
src = fetchurl {
|
|
url = "https://cdn.vibetyper.com/releases/linux/VibeTyper.AppImage";
|
|
sha256 = "sha256-rlbpvUcn84fil7aQci/XANcl/x/u6qIM2dmhypwI7mU=";
|
|
};
|
|
appimageContents = appimageTools.extract {inherit pname version src;};
|
|
in
|
|
appimageTools.wrapType2 {
|
|
inherit pname version src;
|
|
|
|
nativeBuildInputs = [makeWrapper];
|
|
|
|
extraPkgs = pkgs: [pkgs.fuse2];
|
|
|
|
extraInstallCommands = ''
|
|
install -m 444 -D ${appimageContents}/vibe-typer.desktop -t $out/share/applications
|
|
substituteInPlace $out/share/applications/vibe-typer.desktop \
|
|
--replace 'Exec=AppRun --no-sandbox' 'Exec=${pname}'
|
|
install -m 444 -D ${appimageContents}/vibe-typer.png \
|
|
$out/share/icons/hicolor/512x512/apps/vibe-typer.png
|
|
wrapProgram $out/bin/${pname} \
|
|
--set VIBE_DISABLE_WLROOTS_INDICATOR_RULES 1
|
|
'';
|
|
|
|
passthru.updateScript = ./update.sh;
|
|
|
|
meta = {
|
|
description = "VibeTyper - AI-powered typing assistant";
|
|
homepage = "https://vibetyper.com";
|
|
license = lib.licenses.unfree;
|
|
platforms = lib.platforms.linux;
|
|
mainProgram = "vibetyper";
|
|
};
|
|
}
|