m3tam3re
20feae2098
- vibetyper/msty-studio: unversioned AppImage URLs → HEAD/Last-Modified check via custom update.sh, refreshes sha256 when upstream binary changes - zellij-ps: switch to branch-tracking (master tip via Gitea API) since helper-scripts repo has no tags - all three expose passthru.updateScript so the existing CI workflow discovers them via is_custom_update_script
49 lines
1.5 KiB
Nix
49 lines
1.5 KiB
Nix
# last-modified: Wed, 24 Sep 2025 00:17:41 GMT
|
||
{
|
||
appimageTools,
|
||
fetchurl,
|
||
lib,
|
||
nodejs,
|
||
uv,
|
||
python3,
|
||
makeWrapper,
|
||
}: let
|
||
pname = "msty-studio";
|
||
version = "2.0.0-beta.4";
|
||
# Upstream publishes to an unversioned URL — ./update.sh watches Last-Modified
|
||
# and refreshes the sha256 when the binary changes. Bump `version` manually.
|
||
src = fetchurl {
|
||
url = "https://next-assets.msty.studio/app/alpha/linux/MstyStudio_x86_64.AppImage";
|
||
sha256 = "sha256-zJcGK7QEL3ROgVJy13mMdY/437H3Zx8EwSXy7rEhV9w=";
|
||
};
|
||
appimageContents = appimageTools.extractType2 {inherit pname version src;};
|
||
in
|
||
appimageTools.wrapType2 {
|
||
inherit pname version src;
|
||
nativeBuildInputs = [makeWrapper];
|
||
|
||
extraPkgs = pkgs: [
|
||
nodejs
|
||
uv
|
||
python3
|
||
];
|
||
|
||
extraInstallCommands = ''
|
||
install -m 444 -D ${appimageContents}/MstyStudio.desktop -t $out/share/applications
|
||
substituteInPlace $out/share/applications/MstyStudio.desktop \
|
||
--replace 'Exec=AppRun' 'Exec=${pname}'
|
||
install -m 444 -D ${appimageContents}/MstyStudio.png \
|
||
$out/share/icons/hicolor/256x256/apps/MstyStudio.png
|
||
wrapProgram $out/bin/${pname} \
|
||
--prefix PATH : ${nodejs}/bin:${uv}/bin:${python3}/bin
|
||
'';
|
||
passthru.updateScript = ./update.sh;
|
||
|
||
meta = {
|
||
description = "Msty Studio enables advanced, privacy‑preserving AI workflows entirely on your local machine.";
|
||
license = lib.licenses.unfree;
|
||
platforms = lib.platforms.linux;
|
||
mainProgram = "msty-studio";
|
||
};
|
||
}
|