m3ta-chiron
8f2d1beba3
Also bumps the buzz input (0.5.18 -> 0.5.20), which pulls rust-overlay fd2ebb9 where the stdenv.isLinux/isDarwin reads were migrated to stdenv.hostPlatform — eliminating evaluation warnings.
49 lines
1.5 KiB
Nix
49 lines
1.5 KiB
Nix
# last-modified: Wed, 24 Sep 2025 00:17:41 GMT
|
||
{
|
||
appimageTools,
|
||
fetchurl,
|
||
lib,
|
||
nodejs,
|
||
uv,
|
||
python3,
|
||
makeWrapper,
|
||
}: let
|
||
pname = "msty-studio";
|
||
version = "2.0.0-beta.4";
|
||
# Upstream publishes to an unversioned URL — ./update.sh watches Last-Modified
|
||
# and refreshes the sha256 when the binary changes. Bump `version` manually.
|
||
src = fetchurl {
|
||
url = "https://next-assets.msty.studio/app/alpha/linux/MstyStudio_x86_64.AppImage";
|
||
sha256 = "sha256-zJcGK7QEL3ROgVJy13mMdY/437H3Zx8EwSXy7rEhV9w=";
|
||
};
|
||
appimageContents = appimageTools.extract {inherit pname version src;};
|
||
in
|
||
appimageTools.wrapType2 {
|
||
inherit pname version src;
|
||
nativeBuildInputs = [makeWrapper];
|
||
|
||
extraPkgs = pkgs: [
|
||
nodejs
|
||
uv
|
||
python3
|
||
];
|
||
|
||
extraInstallCommands = ''
|
||
install -m 444 -D ${appimageContents}/MstyStudio.desktop -t $out/share/applications
|
||
substituteInPlace $out/share/applications/MstyStudio.desktop \
|
||
--replace 'Exec=AppRun' 'Exec=${pname}'
|
||
install -m 444 -D ${appimageContents}/MstyStudio.png \
|
||
$out/share/icons/hicolor/256x256/apps/MstyStudio.png
|
||
wrapProgram $out/bin/${pname} \
|
||
--prefix PATH : ${nodejs}/bin:${uv}/bin:${python3}/bin
|
||
'';
|
||
passthru.updateScript = ./update.sh;
|
||
|
||
meta = {
|
||
description = "Msty Studio enables advanced, privacy‑preserving AI workflows entirely on your local machine.";
|
||
license = lib.licenses.unfree;
|
||
platforms = lib.platforms.linux;
|
||
mainProgram = "msty-studio";
|
||
};
|
||
}
|